Коллекция JS: MIDI Plugins (1 онлайн

EUGEN27771 · 4 Мар 2015

@Aleksandr Oleynik, многие плагины уже есть,сделанные другими авторами,еще не все выкладывают в stash(http://stash.reaper.fm/tag/JS-Effects).На форуме кокосов можно поиском найти.Многие,наверное,забывают и они так и теряются.
Вот фильтр,типа Вашего

fruitcore · 4 Мар 2015

А эти плагины могут оперировать значением доли, на которой стоит воспроизводимая нота (ну, или курсор воспроизведения)?
Давно хотел такую простенькую утилиту, которая бы для нот близ сильных долей делала бы большее велосити. И чтоб это все настраивалось хоть как-то слайдерами.
А то приходится пока что выкручиваться с groove tools, но это не так быстро, не так наглядно

EUGEN27771 · 4 Мар 2015

@Aleksandr Oleynik, я понял,это на случай если что-то подсмотреть,переделать.
Вот,@fruitcore,спрашивает,и я помню,что точно где-то подобный плагин видел,может даже в стандартных.

Aleksandr Oleynik написал(а):
Не знаю, думаю нет.

Могут,в Рипере есть сис. переменная beat position.Нужно сделать,чтобы,например,при заданных значениях этой переменной velocity была больше,а в остальных случаях меньше на определенныую величину.

fruitcore · 4 Мар 2015

@Aleksandr Oleynik, Например вот, в исходном файле все велосити 100, в итоговом повышены велосити каждой четверти (здесь можно, чтоб была настройка, какая минимально повышаемая доля: в данном случае 1/4, остальные все наоборот ослаблены). Причем вторая доля еще сильнее выделена, а первая самая сильная. В идеале были бы раздельные слайдеры на каждый уровень: на 1/1, на 1/2, на 1/4 и на все остальное. Можно сразу сделать слайдеры и на 1/8, и на 1/16. Мельче наверное уже бессмысленно

Ну и одна только проблемка вырисовывается: не всегда ведь ноты строго по сетке идут, какие-то могут запаздывать, какие-то опережать, грувы всякие свинговые, т.е. по идее нужно какое-то округление позиции, тоже регулируемое
Но на самом деле даже без этого, в таком виде была бы очень полезная примитивная "оживлялка" велосити

EUGEN27771 · 5 Мар 2015

Вот хороший плагин,все настраивается и интерфейс есть,и 16 паттернов http://forum.cockos.com/showthread.php?t=25391

Кстати,там еще упоминается seqbaby,который в настоящий момент уже megababy,включен в стандартные плагины Рипера,оч. клевая штука.

А вот еще круче,

Antonio · 4 Апр 2020

Привет всем. Прошу помощи у тех кто разобрался с js плагинами. Нужен простой плагин, который при получении note off выдаёт note on c velocity например 100. Хочу использовать его для саунддизайна, для более тонкой работы с финальной частью звука, после отпускания клавиши. В FX стоит синтезатор, работает как обычно, после него искомый плагин и после любой сэмплер или синтезатор, доигрывающий ноту. Поиски не дали ничего, несколько часов проковырялся с плагином JS midi note repeater, который выдаёт ноты через заданные промежутки времени, пока клавиша нажата. Почитал документацию к JS. Пока далёк от реализации. Максимум, что получил, тупо меняя местами части кода в JS midi note repeater, это постоянный note on на выходе.

Вот код репитера, то что мне нужно, должно поместиться в 10 строк, если не ошибаюсь. Направьте, пожалуйста, если не займёт много времени.

Код:

desc:MIDI Note Repeater
//tags: MIDI processing

slider1:1<0.1,4>Size (beats)

in_pin:none
out_pin:none

@init
status=0;
status2=128;
memset(status,-1,128);
memset(status2,0,128);

@slider
div=slider1;

@block

while (
midirecv(ts,msg1,msg23) ?
(
  m=msg1&240;
  note=msg23&127;
  (m == 9*16 && msg23>=256) ? (
    status[note]=0;
    vel=(msg23/256);
    vel<1?vel=1:vel>=127?vel=127:vel|=0;
    status2[note]=vel;
    midisend(ts,9*16,note+vel*256); // send note on
  ) : (m == 8*16 || m == 9*16) ? (
    status[note]=-1;
    status2[note]>0.0 ? (
      midisend(ts,8*16,note); // send note off
      status2[note]=0;
    );
  ) : (
    midisend(ts,msg1,msg23);
  );
  bla=1;
);
);

inc = samplesblock/srate*(tempo/60)*2/div;
x=0;
loop(128,
  status[x]>=0.0 ?
  (
    status[x] += inc;
    status[x] >= 1.0 ?
    (
      status[x] -= 1.0;
      status2[x]>0.0 ? midisend(0,8*16,x) : midisend(0,9*16,x - status2[x]*256);
      status2[x]*=-1;
    );
  );
  x+=1;
 
);


@sample

vitalker · 5 Апр 2020

@Antonio, может поможет плагин для обратного назначения?

Код:

/**
 * JSFX Name: Note On under X velocity to Note Off
 * Description: Converts Notes On to Note Off
 * Author: X-Raym
 * Author URI: http://www.extremraym.com
 * Links:
     Forum Thread http://forum.cockos.com/showthread.php?t=181105
     Screenshot https://monosnap.com/file/jSODyOpFNH9W4VxgBW6dByhlGfnAKS.png
 * Donation: http://www.extremraym.com/en/donation
 * Licence: GPL v3
 * REAPER: 5.0
 * Extensions: None
 * Version: 1.0
 */

/**
 * Changelog:
 * v1.0 (2017-11-19)
  + Initial Release
 */

desc:Note On under X velocity to Note Off

slider1:0<0,16,1{Any,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>Input Channel

slider3:0<0,127,1>Velocity Threshold

////////////////////////////////////////////////////////////////////////////////
@init
statNoteOn = $x90;
statNoteOff = $x80;


////////////////////////////////////////////////////////////////////////////////
@slider
inChannel = slider1 - 1;

////////////////////////////////////////////////////////////////////////////////
@block

while
(

  midirecv(offset,msg1,note,vel) ?
  (

    // Extract message type and channel
    status = msg1 & $xF0;
    channel = msg1 & $x0F;

    // Is it on our channel?
    channel == inChannel || inChannel == -1 ?
    (
      
      // Is it a note event?
      status == statNoteOn ?
      (

          // If note is good
          vel <= slider3 ? (
              
              vel = 0;
              msg1 = statNoteOff;
        
          );

      );

    );
    
    midisend(offset,msg1,note,vel);
    
    1; // Force loop to continue until all messages have been processed

  );

);

Antonio · 5 Апр 2020

@vitalker, Спасибо, довольно ясно написано, надеюсь справиться с переделкой.

Antonio · 6 Апр 2020

Получилось. Спасибо @vitalker.

Код:

/**
 * JSFX Name: Note Off to Note On
 * Description: Filtr all note On and converts Notes Off to Note On.
 It's usefull to elaborate release fase in a sound.
 * Author: X-Raym. Modificated by Antonio from rmmedia.ru
 * Author URI: http://www.extremraym.com
 * Links:
     Forum Thread http://forum.cockos.com/showthread.php?t=181105
     Screenshot https://monosnap.com/file/jSODyOpFNH9W4VxgBW6dByhlGfnAKS.png
 * Donation: http://www.extremraym.com/en/donation
 * Licence: GPL v3
 * REAPER: 5.0
 * Extensions: None
 * Version: 1.0
 */

/**
 * Changelog:
 * Note Off to On v.1.0 by Antonio
 * v1.0 (2017-11-19)
  + Initial Release
 */

desc:Note On under 127 velocity to Note Off And all Note Off to Note On

slider1:0<0,16,1{Any,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>Input Channel


////////////////////////////////////////////////////////////////////////////////
@init
statNoteOn = $x90;
statNoteOff = $x80;


////////////////////////////////////////////////////////////////////////////////
@slider
inChannel = slider1 - 1;

////////////////////////////////////////////////////////////////////////////////
@block

while
(

  midirecv(offset,msg1,note,vel) ?
  (

    // Extract message type and channel
    status = msg1 & $xF0;
    channel = msg1 & $x0F;

    // Is it on our channel?
    channel == inChannel || inChannel == -1 ?
    (
      
      // Is it a note event?
      status == statNoteOn ?
      (

          // If note is good
          vel <=127 ? (
              
              vel = 0;
              msg1 = statNoteOff;
        
          );

      );
      // Is it a note off event?
            status == statNoteOff ?
            (
                    msg1 = statNoteOn;
              
                );
      

    );
    
    midisend(offset,msg1,note,vel);
    
    1; // Force loop to continue until all messages have been processed

  );

);

Antonio · 6 Апр 2020

Хаха, перешёл по ссылке в описании плагина и нашёл там

В списке плагинов на фото увидел note off to note on. Загуглил название и нашел это:

Код:

desc:Note off to note on vel 1 filter

// these lines tell Reaper the effect has no audio input/output,
// which enables processing optimizations.
// MIDI-only FX should always have these lines.
in_pin:none
out_pin:none

@init

NOTE_OFF = $x80;
NOTE_ON = $x90;
VEL_ONE = $x100;

@block

  while
  (
    (midirecv(mpos, msg1, msg23)) ?
    (
      ((msg1 & $xF0) == NOTE_OFF) ?
      (
          chan = msg1 & $x0F;
          note = msg23 & $xFF;
        
          msg1 = NOTE_ON | chan;
          msg23 = VEL_ONE | note;
        
       );
    
      midisend(mpos, msg1, msg23);
      
    );
  );

Работает тоже отлично. Upd. Показалось, работает, но не так как мне нужно.

vitalker · 6 Апр 2020

Antonio написал(а):
Работает тоже отлично. Upd. Показалось, работает, но не так как мне нужно.

А ваш плагин работает? Рад был помочь.

Antonio · 6 Апр 2020

vitalker написал(а):
А ваш плагин работает?

Да, работает хорошо. Фильтрует все note on, а все note off меняет на note on. Не называю его своим, т. к измения были минимальными, 3 строчки убрал, 3 добавил. Спасибо ещё раз, без вашей помощи бы не справился.

vitalker · 6 Апр 2020

Antonio написал(а):
Спасибо ещё раз, без вашей помощи бы не справился.

Да пожалуйста, спасибо автору плагина.

Коллекция JS: MIDI Plugins (1 онлайн

Well-Known Member

Вложения

Well-Known Member

Вложения

Well-Known Member

Active Member

Well-Known Member

Well-Known Member

Вложения

Well-Known Member

Active Member

Вложения

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Well-Known Member

Сейчас онлайн (Пользователей: 0, Гостей: 1)